home *** CD-ROM | disk | FTP | other *** search
/ Chip 2007 January, February, March & April / Chip-Cover-CD-2007-02.iso / Pakiet bezpieczenstwa / mini Pentoo LiveCD 2006.1 / mpentoo-2006.1.iso / livecd.squashfs / etc / csh.cshrc < prev    next >
Text File  |  2006-01-09  |  2KB  |  70 lines
  1. ## Gentoo csh.cshrc
  2. ##
  3. ## 2005-11-10 -- Fabian Groffen (grobian@gentoo.org)
  4. ##   * Disabled sourcing environment defaults and additional settings
  5. ##     when having a non-interactive shell.  Bug #104763
  6. ## 2005-09-29 -- Fabian Groffen
  7. ##   * Initial version of a complete redo of this file to fix many bugs
  8. ##     and resolve many annoyances experienced by numerous users
  9. ##
  10.  
  11. ##
  12. ## Load the environment defaults.
  13. ##
  14. if ( $?prompt && -r /etc/csh.env ) then
  15.     source /etc/csh.env
  16. endif
  17.  
  18. ##
  19. ## Make sure our path includes the basic stuff for root and normal users.
  20. ##
  21. set -f path = ( /usr/local/bin /usr/bin /bin /opt/bin $path )
  22. if ( "$uid" == "0" ) then
  23.     set -f path = ( /sbin /usr/sbin /usr/local/sbin $path )
  24. endif
  25.  
  26. if ( $?tcsh && $?prompt ) then
  27.     ##
  28.     ## Set a Gentoo-ish shell prompt with colours
  29.     ##
  30.     set promptchars = "%#"
  31.     if ( "$uid" == "0" ) then
  32.         set prompt = "%{\033[0;1;34m%}(%{\033[0;1;31m%}%m%{\033[0m%}:%{\033[0;1;34m%}%c3%{\033[0;1;34m%}) %{\033[0;1;31m%}%#%{\033[0m%} "
  33.     else
  34.         set prompt = "%{\033[0;1;34m%}(%{\033[0;1;32m%}%m%{\033[0m%}:%{\033[0;1;34m%}%c3%{\033[0;1;34m%}) %{\033[0;1;32m%}%n%{\033[0;1;32m%}%#%{\033[0m%} "
  35.     endif
  36.  
  37.     ##
  38.     ## Change the window title if appropriate
  39.     ##
  40.     if ( $?TERM ) then
  41.         switch ( $TERM )
  42.             case xterm*:
  43.             case rxvt:
  44.             case eterm:
  45.             case Eterm:
  46.             case screen:
  47.             case vt100:
  48.                 if ( "$uid" == "0" ) then
  49.                     set prompt = "%{\033]0;# %m:%~\007%}$prompt"
  50.                 else
  51.                     set prompt = "%{\033]0;%m:%~\007%}$prompt"
  52.                 endif
  53.             breaksw
  54.         endsw
  55.     endif
  56. endif
  57.  
  58. ##
  59. ## Source extensions
  60. ##
  61. if ( $?prompt && -d /etc/profile.d ) then
  62.     set nonomatch
  63.     foreach i ( /etc/profile.d/*.csh )
  64.         if ( -r $i ) then
  65.             source $i
  66.         endif
  67.     end
  68.     unset i nonomatch
  69. endif
  70.